SofiaDB desde el lenguaje Sofía#

La base vive en la carpeta privada de la app (~/.sofia/datos/<id>/.sofiadb/). archivos.* no la ve. Cuando una sentencia o un transaccion { } termina, lo guardado sobrevive a un corte de luz. El detalle del motor está en SofiaDB; el SQL que acepta, en la referencia de SQL; y un recorrido con ejemplos, en el tutorial.

Un ejemplo completo#

app "Citas" id "citas" version "1.0"
permiso consola, datos

tipo Cita { id: entero, profesional: texto, inicio: entero, monto: texto }

fn reservar(prof: texto, inicio: entero) -> texto {
    var r = "RESERVADA"
    intentar {
        transaccion {
            let choca = datos.entero($"SELECT count(*) FROM cita WHERE profesional = {prof} AND inicio = {inicio}")
            si choca > 0 { fallar("HORA_OCUPADA") }
            datos.ejecutar($"INSERT INTO cita (id, profesional, inicio, monto) VALUES ({inicio}, {prof}, {inicio}, {"25.50"})")
        }
    } si falla e {
        r = e
    }
    devolver r
}

fn principal() {
    datos.ejecutar("CREATE TABLE IF NOT EXISTS cita (id INTEGER PRIMARY KEY, profesional TEXT, inicio TIMESTAMPTZ, monto NUMERIC(10,2))")
    consola.escribir_linea(reservar("ana", 1790586000000))
    para c en datos.consultar(Cita, "SELECT id, profesional, inicio, monto FROM cita ORDER BY inicio") {
        consola.escribir_linea($"{c.profesional}: {c.monto} €")
    }
}

Funciones#

Consultas parametrizadas obligatorias#

Entre llaves va un entero, un texto o un logico, o cualquier expresión que dé uno de ellos. Un real se pasa como texto con texto.de_real(x).

Permiso#

permiso consola, datos

Sin permiso datos, las funciones datos.* y transaccion { } no compilan.

Tipos#

Del lenguaje a la base: un entero, texto o logico entre llaves llega con su tipo; un texto se convierte al tipo de la columna como un literal SQL ({"25.50"} a NUMERIC, {"2026-09-28T09:00:00Z"} a TIMESTAMPTZ). Un tipo que no encaja es un fallo recuperable que dice qué columna es.

Reglas#

• SQL: un subconjunto del SQL estándar, en inglés. Todo lo que acepta, sentencia por sentencia, está en la referencia de SQL.
• Sin NULL, como el lenguaje: toda columna tiene valor (NULL e IS NULL son errores). Las columnas que se añaden con ALTER TABLE necesitan DEFAULT. sum de ninguna fila da 0; min y max de ninguna fila son un fallo. Un LEFT JOIN sin pareja y una subconsulta escalar sin filas dan el vacío del tipo, y datos.consultar rechaza dos columnas con el mismo nombre (usa AS).
• Errores recuperables: una clave primaria repetida, un tipo que no encaja o un SQL mal escrito son fallar recuperables con intentar { … } si falla e { … }, con el mensaje del motor en e. Los de restricciones empiezan por un código estable: UNICO_VIOLADO:<indice>, FORANEA_VIOLADA:<restriccion>, COMPROBAR_VIOLADO:<restriccion> y CONFLICTO_SERIALIZACION.
• Transacciones: sin transaccion, cada datos.* es su propia transacción. Dentro de transaccion { } no se puede devolver ni salir con romper o continuar (se guarda el valor en una variable y se devuelve después), ni abrir otra transaccion. Si una sentencia falla dentro del bloque y la app lo recoge con un intentar interior, la transacción ya no admite más sentencias: se deshace al terminar el bloque.
• Repetición automática: si otra transacción confirmó antes un cambio en algo que el bloque leyó, el bloque se repite solo (hasta 5 veces); si sigue chocando, falla con CONFLICTO_SERIALIZACION. Por eso dentro del bloque solo va datos y cálculo: llamar a red, archivos, consola u otro permiso no compila.
• Varias peticiones a la vez (apps web): comparten la base y no se esperan; cada transaccion { } trabaja sobre su propia foto. Así «dos reservan la misma hora» deja una sola reserva.

Límites#

Para copias de seguridad, cifrado y acceso remoto, la línea de órdenes está en sofia datos.